Resolved What is the equivalent code in VB.NET ?

casper · #1 (**permalink**) 12-04-2008, 11:39 PM

Hi There,

I've been trying to convert the below VBA code to VB.NET:

Code:

Option Compare Database

Declare Sub Process Lib "Process.dll" (ByRef sInt As Integer, ByRef sString As MemInfo)

Type MemInfo
    sString As String * 100
End Type

Public Sub test()
    Dim sSize As Integer
    Dim sWord As MemInfo
   
    sSize = 100
    sWord.sString = "Hello: "
    Call Process (sSize , sWord )
   
    MsgBox sWord.sString
    
End Sub

Thanks

JuggaloBrotha · #2 (**permalink**) 12-05-2008, 8:56 AM

Roughly it's something like this:

Code:

Declare Sub Process Lib "Process.dll" (ByRef sInt As Short, ByRef sString As MemInfo)

Structure MemInfo
    <VBFixedString(100)> Dim sString As String
End Structure

Public Sub test()
    Dim sSize As Integer
    Dim sWord As MemInfo
   
    sSize = 100
    sWord.sString = "Hello: "
    Call Process (sSize , sWord)
   
    Messagebox.Show(sWord.sString)
    
End Sub

Don't expect this to work 100% right off the bat, I converted it using notepad.

casper · #3 (**permalink**) 12-07-2008, 10:23 PM

hey mate.. i'm having this error while running in .NET:

Quote:

attempt to read or write protected memory. this is often an indication that other memory is corrupt

I've tested VBA code and working perfectly..

any thoughts?

JuggaloBrotha · #4 (**permalink**) 12-08-2008, 9:02 AM

What line is it erroring on and what's the exact error message? (Posting a screenshot of the error message should be good enough)

casper · #5 (**permalink**) 12-08-2008, 4:51 PM

attached is the file

MattP · #6 (**permalink**) 12-08-2008, 4:55 PM

Visual Studio 2005 converted it to this:

Code:

	Declare Sub Process Lib "Process.dll" (ByRef sInt As Short, ByRef sString As MemInfo)

	Structure MemInfo
		<VBFixedString(100), System.Runtime.InteropServices.MarshalAs(System.Runtime.InteropServices.UnmanagedType.ByValArray, SizeConst:=100)> Public sString() As Char
	End Structure

	Public Sub test()
		Dim sSize As Short
		Dim sWord As MemInfo

		sSize = 100
		sWord.sString = "Hello: "
		Call Process(sSize, sWord)

		MsgBox(sWord.sString)

	End Sub

casper · #7 (**permalink**) 12-08-2008, 5:05 PM

Hey mate the following error has occurred.

P.S: the VBA code is working correctly. I just don't understand why the memory allocation is different between VBA and .NET! any further thoughts?

thanks

casper · #8 (**permalink**) 12-08-2008, 5:21 PM

hey mate.. i got it working...

changed the following code:

Code:

Structure Meminfo
        <VBFixedString(100), System.Runtime.InteropServices.MarshalAs(System.Runtime.InteropServices.UnmanagedType.ByValArray, SizeConst:=100)> Dim sCobol As String
    End Structure

to:

Code:

Structure Meminfo
        <VBFixedString(100), System.Runtime.InteropServices.MarshalAs(System.Runtime.InteropServices.UnmanagedType.ByValTStr, SizeConst:=100)> Dim sCobol As String
    End Structure

MANY THANKS FOR YOUR HELP.. REALLY REALLY REALLY APPRECIATED!!!!

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Currently Active Users Viewing This Thread: 1 (0 members and 1 guests)